Converting Ó Raghallaigh (2010)

This notebook contains a re-implementation of the "global" phonetiser from Brian Ó Raghallaigh's Ph.D. thesis using rbg2p, along with the "local" phonetiser for Kerry.

The global phonetiser here is essentially the same as the earlier one, except the output phonemes are lowercase, and there are no spaces between output phonemes, to work around some slight limitations of rbg2p.

Brian Ó Raghallaigh (2010). Multi-dialect phonetisation for Irish text-to-speech synthesis: a modular approach. (Doctoral thesis, Trinity College, Dublin), Appendix B.1

%%writefile oraghallaigh.g2p
CHARACTER_SET "aábcdeéfghiíjklmnoópqrstuúvwxyz'-’"
DEFAULT_PHONEME "_"
PHONEME_DELIMITER ""

VAR CONS [bcdfghjklmnpqrstvwxyz]
VAR CONSS [bcdfghjklmnpqrstvwxyz]*
VAR CONSP [bcdfghjklmnpqrstvwxyz]+
VAR NONSYLLABIC [ábcdfghjklmnópqrstúvwxyz]

// broad future/conditional endings
VAR BFCE (á|adh|aidh|aidís|aimid|aimis|ainn|as)
// slender future/conditional endings
VAR SFCE (eá|eadh|idh|idís|imid|imis|inn)
VAR FMP [fmp]
VAR LNRP [lnr]+
VAR DNLST [dnlst]
VAR RDNLR (rd|rn|rl|rr)
VAR VOWEL [aáeéiíoóuú]
VAR VOWELS [aáeéiíoóuú]*
VAR VOWELP [aáeéiíoóuú]+
// left context short broad vowel
VAR LCSBV (ea|io|iu|a|o|u)
// left context short slender vowel
VAR LCSSV (ai|eai|ei|e|iui|i|oi|ui)
// left context broad vowel
VAR LCBV (adh|ae|ao|aá|ea|eá|eo|éa|io|iu|iú|ío|oó|uío|ua|u|ú)
// left context slender vowel
VAR LCSV (aei|aidh|ai|aí|aoi|ái|eai|eái|ei|eoi|e|éi|é|iai|iui|iúi|i|í|oi|ói|uai|ui|uí|úi)
VAR LCSVS (aei|aidh|ai|aí|aoi|ái|eai|eái|ei|eoi|e|éi|é|iai|iui|iúi|i|í|oi|ói|uai|ui|uí|úi)*
// right context slender vowel
VAR RCSV (eai|ea|eái|eá|ei|eoi|eo|e|éa|éi|é|iai|ia|io|iui|iu|iúi|iú|i|ío|í)
// left context long vowel
VAR LCLV (aei|ae|aoi|ao|ái|á|eái|eá|eoi|eó|eo|éi|é|iúi|iú|ío|í|ói|ó|uío|uí|úi|ú)
// left context slender long vowel
VAR LCSLV (aei|aidh|aoi|ái|eái|eoi|éi|é|iúi|í|ói|uai|uí|úi)

ádh -> aa
ái -> aa
á -> aa

abh -> abh
adh -> adh / _ #
adh -> ai
agh -> ai
aei -> ee
ae -> ee
aíodh -> íodh / _ #
aío -> aío
aí -> ii
aidh -> idh / _ #
aidh -> ai
aigh -> igh / _ #
aigh -> ai
aithe -> ithe / _ #
ai -> ∅ / # CONSS VOWELS (abh|adh|agh|amh|ódh|ogh|omh|umh) _ CONSP
ai -> ∅ / # CONSS (obh|odh) _ CONSP

ai -> aa / # CONSS _ RDNLR
ai -> a / # CONSS _
ai -> @@ / VOWELP CONSP _
ai -> a
amh -> amh / _ #
amh -> au
aoi -> ao
ao -> ao

a -> ∅ / # CONSS VOWELS (abh|adh|agh|amh|ódh|ogh|omh|umh) _ CONSP
a -> ∅ / # CONSS (obh|odh) _ CONSP

# addition
a -> ∅ / # CONSS VOWELS ogh _ #
omh -> OO / (gc|ch|c) _ (ai|a) r

a -> aa / # CONSS _ RDNLR
a -> a / # CONSS _

a -> @@ / VOWELP CONSP _
a -> a

éa -> ee
éi -> ee
é -> ee

eái -> aa
eá -> aa
eabh -> abh
eadh -> adh / _ #
eadh -> au
eagh -> ai
eai -> a
eamh -> amh / _ #
eamh -> au / # CONSS _
# VOWEL, or VOWELS ??
ea -> ∅ / # CONSS VOWEL igh _ CONSP

ea -> aa / # CONSS _ RDNLR
ea -> a / # CONSS _

ea -> @@ / VOWELP CONSP _
ea -> a

eidh -> eidh
eigh -> eigh

ei -> ee / # CONSS _ RDNLR #
ei -> ee / # CONSS _ RDNLR NONSYLLABIC
ei -> e / # CONSS _
ei -> e
eódh -> oo
eoi -> oo
eó -> oo
eo -> oo
e -> e / # CONSS _
e -> @@ / VOWELP CONSP _
e -> e

íodh -> íodh / _ #
ío -> ii
í -> ii

iadh -> i@
iath -> i@
iai -> i@
ia -> i@
idh -> idh
igh -> igh
io -> io
ithe -> ithe / _ #
iúi -> uu
iú -> uu
iubh -> ubh
iumh -> uu
iui -> uu
iu -> u
i -> ∅ / # CONSS VOWEL idh _ CONSP #
i -> ∅ / # CONSS VOWEL igh _ CONSP
i -> @@ / VOWELP CONSP _
i -> I

ódh -> ódh / _ #
ói -> oo
ó -> oo

obh -> obh
odh -> odh
ogh -> ogh

oí -> ii
oidh -> oidh
oigh -> oigh

oi -> oo / # CONSS _ RDNLR
oi -> @@ / # VOWELP CONSP _
oi -> oi
omh -> omh

o -> oo / # CONSS _ RDNLR #
o -> oo / # CONSS _ RDNLR NONSYLLABIC
o -> o / # VOWELP CONSP _
o -> o

úi -> uu
ú -> uu

uath -> u@
uai -> u@
ua -> u@
ubh -> ubh
ue -> e

ui -> uu / # CONSS _ RDNLR #
ui -> uu / # CONSS _ RDNLR NONSYLLABIC
ui -> i / # CONSS _
ui -> @@ / VOWELP CONSP _
ui -> ui
uío -> ii
uí -> ii
umh -> uu

u -> uu / # CONSS _ RDNLR
u -> u / # CONSS _
u -> @@ / VOWELP CONSP _
u -> u

bf -> p / _ BFCE #
bf -> pj / _ SFCE #
bhf -> vj / # _ CONSS RCSV #
bhf -> vj / # _ CONSS RCSV NONSYLLABIC
bhf -> v / # _
bhf -> f / _ BFCE #
bhf -> fj / _ SFCE #
bh -> @@ v / # LCSBV LNRP _
bh -> @@ v / NONSYLLABIC LCSBV LNRP _
bh -> @@ vj / # LCSSV LNRP _
bh -> @@ vj / NONSYLLABIC LCSSV LNRP _

bh -> vj / # _ CONSS RCSV #
bh -> vj / # _ CONSS RCSV NONSYLLABIC
bh -> v / # _

bh -> vj / _ CONSS RCSV #
bh -> vj / _ CONSS RCSV NONSYLLABIC
bh -> vj / # LCSV CONSP _
bh -> vj / NONSYLLABIC LCSV CONSP _
bh -> vj / # LCSV _
bh -> vj / NONSYLLABIC LCSV _
bh -> v
 
bp -> bj / # _ CONSS RCSV #
bp -> bj / # _ CONSS RCSV NONSYLLABIC
bp -> b / # _

bth -> p / LCBV CONSS _
bth -> pj / LCSV CONSS _

b -> @@ b / # LCSBV LNRP _
b -> @@ b / NONSYLLABIC LCSBV LNRP _
b -> @@ bj / # LCSSV LNRP _
b -> @@ bj / NONSYLLABIC LCSSV LNRP _

b -> bj / _ CONSS RCSV #
b -> bj / _ CONSS RCSV NONSYLLABIC
b -> bj / # LCSV CONSP _
b -> bj / NONSYLLABIC LCSV CONSP _
b -> bj / # LCSV _
b -> bj / NONSYLLABIC LCSV _
b -> b

cf -> k / _ BFCE #
cf -> kj / _ SFCE #

chf -> x / _ BFCE #
chf -> xj / _ SFCE #

ch -> @@ x / # LCSBV LNRP _
ch -> @@ x / NONSYLLABIC LCSBV LNRP _
ch -> @@ xj / # LCSSV LNRP _
ch -> @@ xj / NONSYLLABIC LCSSV LNRP _

ch -> xj / # _ CONSS RCSV #
ch -> xj / # _ CONSS RCSV NONSYLLABIC
ch -> x / # _

ch -> xj / _ CONSS RCSV #
ch -> xj / _ CONSS RCSV NONSYLLABIC
ch -> xj / # LCSV CONSP _
ch -> xj / NONSYLLABIC LCSV CONSP _
ch -> xj / # LCSV _
ch -> xj / NONSYLLABIC LCSV _
ch -> x
 
cth -> k / LCBV CONSS _
cth -> kj / LCSV CONSS _

c -> kj / _ CONSS RCSV #
c -> kj / _ CONSS RCSV NONSYLLABIC
c -> kj / # LCSV CONSP _
c -> kj / NONSYLLABIC LCSV CONSP _
c -> kj / # LCSV _
c -> kj / NONSYLLABIC LCSV _
c -> k

df -> t / _ BFCE #
df -> tj / _ SFCE #

dha -> ∅ / # LCLV _
dha -> ∅ / NONSYLLABIC LCLV _
dh -> gfj / # LCSLV _
dh -> gfj / NONSYLLABIC LCSLV _
dh -> gfj / # CONSS LCSVS _ #
dh -> ∅ / # LCLV _
dh -> ∅ / NONSYLLABIC LCLV _

dh -> gfj / # _ CONSS RCSV #
dh -> gfj / # _ CONSS RCSV NONSYLLABIC
dh -> gf / # _

dh -> gfj / _ CONSS RCSV #
dh -> gfj / _ CONSS RCSV NONSYLLABIC
dh -> gfj / # LCSV CONSP _
dh -> gfj / NONSYLLABIC LCSV CONSP _
dh -> gfj / # LCSV _
dh -> gfj / NONSYLLABIC LCSV _
dh -> gf

dt -> dj / # _ CONSS RCSV #
dt -> dj / # _ CONSS RCSV NONSYLLABIC
dt -> d / # _

dt -> t / LCBV CONSS _
dt -> tj / LCSV CONSS _

d -> dj / _ CONSS RCSV #
d -> dj / _ CONSS RCSV NONSYLLABIC
d -> dj / # LCSV CONSP _
d -> dj / NONSYLLABIC LCSV CONSP _
d -> dj / # LCSV _
d -> dj / NONSYLLABIC LCSV _
d -> d

fh -> ∅
f -> h / VOWEL _ BFCE #
f -> hj / VOWEL _ SFCE #

f -> @@ f / # LCSBV LNRP _
f -> @@ f / NONSYLLABIC LCSBV LNRP _
f -> @@ fj / # LCSSV LNRP _
f -> @@ fj / NONSYLLABIC LCSSV LNRP _

f -> fj / _ CONSS RCSV #
f -> fj / _ CONSS RCSV NONSYLLABIC
f -> fj / # LCSV CONSP _
f -> fj / NONSYLLABIC LCSV CONSP _
f -> fj / # LCSV _
f -> fj / NONSYLLABIC LCSV _
f -> f

gc -> gj / # _ CONSS RCSV #
gc -> gj / # _ CONSS RCSV NONSYLLABIC
gc -> g / # _

gf -> k / _ BFCE #
gf -> kj / _ SFCE #

gh -> gfj / # _ CONSS RCSV #
gh -> gfj / # _ CONSS RCSV NONSYLLABIC
gh -> gf / # _

gh -> gfj / # LCSLV _
gh -> gfj / NONSYLLABIC LCSLV _
gh -> gfj / # CONSS LCSVS _ #
gh -> ∅ / # LCLV _
gh -> ∅ / NONSYLLABIC LCLV _

gh -> gfj / _ CONSS RCSV #
gh -> gfj / _ CONSS RCSV NONSYLLABIC
gh -> gfj / # LCSV CONSP _
gh -> gfj / NONSYLLABIC LCSV CONSP _
gh -> gfj / # LCSV _
gh -> gfj / NONSYLLABIC LCSV _
gh -> gf

gth -> k / LCBV CONSS _
gth -> kj / LCSV CONSS _

g -> @@ g / # LCSBV LNRP _
g -> @@ g / NONSYLLABIC LCSBV LNRP _
g -> @@ gj / # LCSSV LNRP _
g -> @@ gj / NONSYLLABIC LCSSV LNRP _

g -> gj / _ CONSS RCSV #
g -> gj / _ CONSS RCSV NONSYLLABIC
g -> gj / # LCSV CONSP _
g -> gj / NONSYLLABIC LCSV CONSP _
g -> gj / # LCSV _
g -> gj / NONSYLLABIC LCSV _
g -> g

h -> hj / _ CONSS RCSV #
h -> hj / _ CONSS RCSV NONSYLLABIC
h -> hj / # LCSV CONSP _
h -> hj / NONSYLLABIC LCSV CONSP _
h -> hj / # LCSV _
h -> hj / NONSYLLABIC LCSV _
h -> h

j -> djzj

k -> kj / _ CONSS RCSV #
k -> kj / _ CONSS RCSV NONSYLLABIC
k -> kj / # LCSV CONSP _
k -> kj / NONSYLLABIC LCSV CONSP _
k -> kj / # LCSV _
k -> kj / NONSYLLABIC LCSV _
k -> k

llf -> ll_d / _ BFCE #
llf -> llj_d / _ SFCE #

llth -> ll_d / LCBV CONSS _
llth -> llj_d / LCSV CONSS _

ll -> llj / _ CONSS RCSV #
ll -> llj / _ CONSS RCSV NONSYLLABIC
ll -> llj / # LCSV CONSP _
ll -> llj / NONSYLLABIC LCSV CONSP _
ll -> llj / # LCSV _
ll -> llj / NONSYLLABIC LCSV _
ll -> ll

lf -> ll_d / _ BFCE #
lf -> lj_d / _ SFCE #

lth -> ll_d / LCBV CONSS _
lth -> lj_d / LCSV CONSS _

l -> lj / _ CONSS RCSV #
l -> lj / _ CONSS RCSV NONSYLLABIC
l -> lj / # LCSV CONSP _
l -> lj / NONSYLLABIC LCSV CONSP _
l -> lj / # LCSV _
l -> lj / NONSYLLABIC LCSV _
l -> ll

mb -> mj / # _ CONSS RCSV #
mb -> mj / # _ CONSS RCSV NONSYLLABIC
mb -> m / # _

mf -> m_d / _ BFCE #
mf -> mj_d / _ SFCE #

mhf -> f / _ BFCE #
mhf -> fj / _ SFCE #

mh -> vj / # _ CONSS RCSV #
mh -> vj / # _ CONSS RCSV NONSYLLABIC
mh -> v / # _

mh -> @@ v / # LCSBV LNRP _
mh -> @@ v / NONSYLLABIC LCSBV LNRP _
mh -> @@ vj / # LCSSV LNRP _
mh -> @@ vj / NONSYLLABIC LCSSV LNRP _

mh -> vj / _ CONSS RCSV #
mh -> vj / _ CONSS RCSV NONSYLLABIC
mh -> vj / # LCSV CONSP _
mh -> vj / NONSYLLABIC LCSV CONSP _
mh -> vj / # LCSV _
mh -> vj / NONSYLLABIC LCSV _
mh -> v

mth -> m_d / LCBV CONSS _
mth -> mj_d / LCSV CONSS _

m -> @@ m / # LCSBV LNRP _
m -> @@ m / NONSYLLABIC LCSBV LNRP _
m -> @@ mj / # LCSSV LNRP _
m -> @@ mj / NONSYLLABIC LCSSV LNRP _

m -> mj / _ CONSS RCSV #
m -> mj / _ CONSS RCSV NONSYLLABIC
m -> mj / # LCSV CONSP _
m -> mj / NONSYLLABIC LCSV CONSP _
m -> mj / # LCSV _
m -> mj / NONSYLLABIC LCSV _
m -> m

nnf -> nn_d / _ BFCE #
nnf -> nnj_d / _ SFCE #

nnth -> nn_d / LCBV CONSS _
nnth -> nnj_d / LCSV CONSS _

nn -> nnj / _ CONSS RCSV #
nn -> nnj / _ CONSS RCSV NONSYLLABIC
nn -> nnj / # LCSV CONSP _
nn -> nnj / NONSYLLABIC LCSV CONSP _
nn -> nnj / # LCSV _
nn -> nnj / NONSYLLABIC LCSV _
nn -> nn

n- -> nj / # _ RCSV #
n- -> nj / # _ RCSV NONSYLLABIC
n- -> nn / # _

nd -> nnj / # _ CONSS RCSV #
nd -> nnj / # _ CONSS RCSV NONSYLLABIC
nd -> nn / # _

nf -> nn_d / _ BFCE #
nf -> nj_d / _ SFCE #

ngf -> ng_d / _ BFCE #
ngf -> ngj_d / _ SFCE #

ngth -> ng_d / LCBV CONSS _
ngth -> ngj_d / LCSV CONSS _

ng -> ngj / # _ CONSS RCSV #
ng -> ngj / # _ CONSS RCSV NONSYLLABIC
ng -> ng / # _
ng -> nj / # LCSV _ t #
ng -> nj / NONSYLLABIC LCSV _ t #

ng -> ngj / _ CONSS RCSV #
ng -> ngj / _ CONSS RCSV NONSYLLABIC
ng -> ngj / # LCSV CONSP _
ng -> ngj / NONSYLLABIC LCSV CONSP _
ng -> ngj / # LCSV _
ng -> ngj / NONSYLLABIC LCSV _
ng -> ng

nth -> nn_d / LCBV CONSS _
nth -> nj_d / LCSV CONSS _

n -> ngj / # LCSV _ c
n -> ngj / NONSYLLABIC LCSV _ c
n -> ng / _ c

n -> nj / _ CONSS RCSV #
n -> nj / _ CONSS RCSV NONSYLLABIC
n -> nj / # LCSV CONSP _
n -> nj / NONSYLLABIC LCSV CONSP _
n -> nj / # LCSV _
n -> nj / NONSYLLABIC LCSV _
n -> nn

pf -> p / _ BFCE #
pf -> pj / _ SFCE #

ph -> fj / # _ CONSS RCSV #
ph -> fj / # _ CONSS RCSV NONSYLLABIC
ph -> f / # _

ph -> fj / _ CONSS RCSV #
ph -> fj / _ CONSS RCSV NONSYLLABIC
ph -> fj / # LCSV CONSP _
ph -> fj / NONSYLLABIC LCSV CONSP _
ph -> fj / # LCSV _
ph -> fj / NONSYLLABIC LCSV _
ph -> f

pth -> p / LCBV CONSS _
pth -> pj / LCSV CONSS _

p -> pj / _ CONSS RCSV #
p -> pj / _ CONSS RCSV NONSYLLABIC
p -> pj / # LCSV CONSP _
p -> pj / NONSYLLABIC LCSV CONSP _
p -> pj / # LCSV _
p -> pj / NONSYLLABIC LCSV _
p -> p

# really? there's a 'W' in the phoneset
q -> k v

rrf -> rr_d / _ BFCE #
rrf -> rrj_d / _ SFCE #

rrth -> rr_d / LCBV CONSS _
rrth -> rrj_d / LCSV CONSS _

rr -> rrj / _ CONSS RCSV #
rr -> rrj / _ CONSS RCSV NONSYLLABIC
rr -> rrj / # LCSV CONSP _
rr -> rrj / NONSYLLABIC LCSV CONSP _
rr -> rrj / # LCSV _
rr -> rrj / NONSYLLABIC LCSV _
rr -> rr

rf -> r_d / _ BFCE #
rf -> rj_d / _ SFCE #

rth -> r_d / LCBV CONSS _
rth -> rj_d / LCSV CONSS _

r -> r / # s _
r -> r / # _
r -> r / _ DNLST

r -> rj / _ CONSS RCSV #
r -> rj / _ CONSS RCSV NONSYLLABIC
r -> rj / # LCSV CONSP _
r -> rj / NONSYLLABIC LCSV CONSP _
r -> rj / # LCSV _
r -> rj / NONSYLLABIC LCSV _
r -> r

sf -> s / _ BFCE #
sf -> sj / _ SFCE #

shl -> lj_d / _ CONSS RCSV #
shl -> lj_d / _ CONSS RCSV NONSYLLABIC
shl -> ll_d
shm -> mj_d / _ CONSS RCSV #
shm -> mj_d / _ CONSS RCSV NONSYLLABIC
shm -> m_d
shn -> nj_d / _ CONSS RCSV #
shn -> nj_d / _ CONSS RCSV NONSYLLABIC
shn -> nn_d
shr -> rj_d / _ CONSS RCSV #
shr -> rj_d / _ CONSS RCSV NONSYLLABIC
shr -> r_d

sh -> xj / # _ CONSS RCSV #
sh -> xj / # _ CONSS RCSV NONSYLLABIC
sh -> h / # _

sh -> xj / _ CONSS RCSV #
sh -> xj / _ CONSS RCSV NONSYLLABIC
sh -> xj / # LCSV CONSP _
sh -> xj / NONSYLLABIC LCSV CONSP _
sh -> xj / # LCSV _
sh -> xj / NONSYLLABIC LCSV _
sh -> h

s -> s / # _ r
s -> s / # _ FMP CONSS RCSV #
s -> s / # _ FMP CONSS RCSV NONSYLLABIC

s -> sj / _ CONSS RCSV #
s -> sj / _ CONSS RCSV NONSYLLABIC
s -> sj / # LCSV CONSP _
s -> sj / NONSYLLABIC LCSV CONSP _
s -> sj / # LCSV _
s -> sj / NONSYLLABIC LCSV _
s -> s

t- -> tj / # _ RCSV #
t- -> tj / # _ RCSV NONSYLLABIC
t- -> t / # _

tf -> t / _ BFCE #
tf -> tj / _ SFCE #

// "hack for compound boundaries"
th -> ∅ / _ CONS h

thb -> pj / _ CONSS RCSV #
thb -> pj / _ CONSS RCSV NONSYLLABIC
thb -> p
thc -> kj / _ CONSS RCSV #
thc -> kj / _ CONSS RCSV NONSYLLABIC
thc -> k
thd -> tj / _ CONSS RCSV #
thd -> tj / _ CONSS RCSV NONSYLLABIC
thd -> t

thf -> h / _ BFCE #
thf -> xj / _ SFCE #

thl -> lj_d / _ CONSS RCSV #
thl -> lj_d / _ CONSS RCSV NONSYLLABIC
thl -> ll_d
thm -> mj_d / _ CONSS RCSV #
thm -> mj_d / _ CONSS RCSV NONSYLLABIC
thm -> m_d
thn -> nj_d / _ CONSS RCSV #
thn -> nj_d / _ CONSS RCSV NONSYLLABIC
thn -> nn_d
thp -> pj / _ CONSS RCSV #
thp -> pj / _ CONSS RCSV NONSYLLABIC
thp -> p
thr -> rj_d / _ CONSS RCSV #
thr -> rj_d / _ CONSS RCSV NONSYLLABIC
thr -> r_d
ths -> sj / _ CONSS RCSV #
ths -> sj / _ CONSS RCSV NONSYLLABIC
ths -> s
tht -> tj / _ CONSS RCSV #
tht -> tj / _ CONSS RCSV NONSYLLABIC
tht -> t

th -> hj / # _ CONSS RCSV #
th -> hj / # _ CONSS RCSV NONSYLLABIC
th -> h / # _

th -> hj / _ CONSS RCSV #
th -> hj / _ CONSS RCSV NONSYLLABIC
th -> hj / # LCSV CONSP _
th -> hj / NONSYLLABIC LCSV CONSP _
th -> hj / # LCSV _
th -> hj / NONSYLLABIC LCSV _
th -> h

ts -> tj / # _ CONSS RCSV #
ts -> tj / # _ CONSS RCSV NONSYLLABIC
ts -> t / # _

t -> tj / _ CONSS RCSV #
t -> tj / _ CONSS RCSV NONSYLLABIC
t -> tj / # LCSV CONSP _
t -> tj / NONSYLLABIC LCSV CONSP _
t -> tj / # LCSV _
t -> tj / NONSYLLABIC LCSV _
t -> t

v -> vj / _ CONSS RCSV #
v -> vj / _ CONSS RCSV NONSYLLABIC
v -> vj / # LCSV CONSP _
v -> vj / NONSYLLABIC LCSV CONSP _
v -> vj / # LCSV _
v -> vj / NONSYLLABIC LCSV _
v -> v

w -> v

x- -> e kj s
x -> zj

y -> gfj

z -> zj / _ CONSS RCSV #
z -> zj / _ CONSS RCSV NONSYLLABIC
z -> zj / # LCSV CONSP _
z -> zj / NONSYLLABIC LCSV CONSP _
z -> zj / # LCSV _
z -> zj / NONSYLLABIC LCSV _
z -> z

' -> ∅
’ -> ∅
- -> ∅

TEST ádh -> aa
TEST áiseanna -> aa sj @@ nn @@
TEST áthas -> aa h @@ s
TEST abhainn -> abh nnj
TEST bualadh -> b u@ ll adh
TEST sadhbh -> s ai v
TEST saghas -> s ai s
TEST gaeilge -> g ee lj gj @@
TEST saolaíodh -> s ao ll íodh
TEST gardaí -> g aa r d ii
TEST dúnfaidh -> d uu nn_d idh
TEST aidhm -> ai mj
TEST cheadaigh -> xj a d igh
TEST aighneas -> ai nj @@ s
TEST diúltaithe -> dj uu ll t ithe
TEST seabhaic -> sj abh kj
TEST feadhain -> fj au nj
TEST teaghais -> tj ai sj
TEST eamhain -> au nj
TEST lobhair -> ll obh rj
TEST leódhais -> lj oo sj
TEST bodhair -> b odh rj
TEST eoghain -> oo nj
TEST broghais -> b r ogh sj
TEST comhair -> k oo rj
TEST ciumhais -> kj uu sj
TEST airde -> aa r dj @@
TEST cait -> k a tj
TEST sodair -> s o d @@ rj
TEST ait -> a tj
TEST déanamh -> dj ee nn amh
TEST amharc -> au r k
TEST gaoil -> g ao lj
TEST gaol -> g ao ll
TEST seabhac -> sj abh k
TEST ceadharlach -> kj au r ll @@ x
TEST teaghasán -> tj ai s aa nn
TEST lobhar -> ll obh r
TEST leódhas -> lj oo s
TEST bodhar -> b odh r
TEST eoghan -> oo nn
TEST bogha -> b ogh
TEST comhar -> k oo r
TEST dumhach -> d uu x
TEST ard -> aa r d
TEST cat -> k a t
TEST sodar -> s o d @@ r
TEST at -> a t
TEST éan -> ee nn
TEST éiníní -> ee nj ii nj ii
TEST é -> ee
TEST sheáin -> xj aa nj
TEST seán -> sj aa nn
TEST seabhac -> sj abh k
TEST seinneadh -> sj e nnj adh
TEST ceadharlach -> kj au r ll @@ x
TEST teaghlach -> tj ai ll @@ x
TEST beairic -> bj a rj @@ kj
TEST áireamh -> aa rj amh
TEST sleamhnán -> sj lj au nn aa nn
TEST oighear -> oigh r
TEST ceard -> kj aa r d
TEST cead -> kj a d
TEST áireamhán -> aa rj @@ v aa nn
TEST eas -> a s
TEST feidhm -> fj eidh mj
TEST leigheas -> lj eigh s
TEST ceird -> kj ee r dj
TEST deis -> dj e sj
TEST eitpheil -> e tj fj e lj
TEST ceoil -> kj oo lj
TEST bainseó -> b a nj sj oo
TEST ceol -> kj oo ll
TEST uile -> i lj @@
TEST ceannaíodh -> kj a nn íodh
TEST síos -> sj ii s
TEST sí -> sj ii
TEST siadhail -> sj i@ lj
TEST sciath -> sj kj i@
TEST riail -> r i@ lj
TEST siad -> sj i@ d
TEST seinnfidh -> sj e nnj_d idh
TEST cheannaigh -> xj a nn igh
TEST fios -> fj io s
TEST imithe -> i mj ithe
TEST siúil -> sj uu lj
TEST siúl -> sj uu ll
TEST tiubh -> tj ubh
TEST ciumhais -> kj uu sj
TEST giuirléid -> gj uu r lj ee dj
TEST fiuch -> fj u x
TEST leighis -> lj eigh sj
TEST foighid -> f oigh dj
TEST aithris -> a rj_d @@ sj
TEST sin -> sj i nj
TEST cheannódh -> xj a nn ódh
TEST óil -> oo lj
TEST ól -> oo ll
TEST lobhadh -> ll obh adh
TEST todhchaí -> t odh x ii
TEST toghadh -> t ogh adh
TEST oíche -> ii xj @@
TEST oidhe -> oidh @@
TEST oighear -> oigh r
TEST boird -> b oo r dj
TEST soir -> s oi rj
TEST comhar -> k oo r
TEST bord -> b oo r d
TEST bos -> b o s
TEST súil -> s uu lj
TEST súl -> s uu ll
TEST uathúil -> u@ uu lj
TEST uaine -> u@ nj @@
TEST uan -> u@ nn
TEST subh -> s ubh
TEST bhuel -> v e ll
TEST guird -> g uu r dj
TEST cuid -> k i dj
TEST uile -> i lj @@
TEST bruíon -> b r ii nn
TEST bruíne -> b r ii nj @@
TEST cumhacht -> k uu x t
TEST burdún -> b uu r d uu nn
TEST cur -> k u r
TEST bus -> b u s
TEST scuabfaidh -> s k u@ p idh
TEST clibfidh -> kj lj i pj idh
TEST scuabfadh -> s k u@ p adh
TEST clibfeadh -> kj lj i pj adh
TEST bhfáinne -> v aa nnj @@
TEST bhfianaise -> vj i@ nn @@ sj @@
TEST scríobhfaidh -> sj kj rj ii f idh
TEST díbhfidh -> dj ii fj idh
TEST scríobhfadh -> sj kj rj ii f adh
TEST díbhfeadh -> dj ii fj adh
TEST searbh -> sj a r @@ v
TEST seirbhís -> sj e rj @@ vj ii sj
TEST bhrostaigh -> v r o s t igh
TEST bhris -> vj rj i sj
TEST coibhín -> k oi vj ii nj
TEST bpáistí -> b aa sj tj ii
TEST bpéisteanna -> bj ee sj tj @@ nn @@
TEST scuabtha -> s k u@ p @@
TEST clibthe -> kj lj i pj @@
TEST borb -> b o r @@ b
TEST seirbiach -> sj e rj @@ bj i@ x
TEST bróna -> b r oo nn @@
TEST brian -> bj rj i@ nn
TEST leódhas -> lj oo s
TEST t-uisce -> t ui sj kj @@
TEST t-éabhlóidí -> tj ee v ll oo dj ii
TEST atfaidh -> a t idh
TEST titfidh -> tj i tj idh
TEST athdhéanamh -> a gfj ee nn amh
TEST meathfadh -> mj a h adh
TEST rithfeadh -> r i xj adh
TEST bláthra -> b ll aa r_d @@
TEST tharla -> h aa r ll @@
TEST thit -> hj i tj
TEST tseachtain -> tj a x t @@ nj
TEST tsagairt -> t a g @@ r tj
TEST teann -> tj a nn
TEST tit -> tj i tj
TEST togra -> t o g r @@
TEST sadhbh -> s ai v
TEST bhéal -> vj ee ll
TEST bhéil -> vj ee lj

%%writefile oraghallaigh-cd.g2p
CHARACTER_SET "abcdefghiíjklmnoóprstuvwxz@.012-_"
DEFAULT_PHONEME "_"
PHONEME_DELIMITER " "

VAR BC (p|b|f|v|m_d|m|t_|t|d_|d|ll_d|ll|l_d|l|nn_d|nn|n_d|n|rr_d|r_d|rr|r|s|z|k|g|x|gf|ng_d|ng|h)
VAR LLJ (llj|nnj|rrj|mj)
VAR LL (ll|nn|rr|m)

aa -> aa
abh -> au
adh -> @ x
agh -> ai
aío -> i@
amh -> @ v
ai -> ai
ao -> ee
au -> au
a -> ai / _ LLJ
a -> au / _ LL
a -> a

ee -> i@ / _ BC
ee -> ee
eidh -> e gj / _ #
eidh -> ai
eigh -> ai
e -> e

idh -> @ gj
igh -> @ gj
íodh -> i@ x
ithe -> @ . 0 h @
i@ -> i@
ii -> ii
io -> i
i -> ii / _ LLJ #
i -> i

obh -> au
ódh -> oo x
odh -> au
ogh -> au
oidh -> ai
oigh -> ai
oi -> ii / _ LLJ #
oi -> i
omh -> au
oo -> oo
o -> au / _ LL #
o -> o

ubh -> u v / _ #
ubh -> @ v
u@ -> u@
ui -> ii / _ LLJ
ui -> i
uu -> uu
u -> u

@@ -> @

pj -> pj
p -> p
bj -> bj
b -> b
fj -> fj
f -> f
vj -> vj
v -> v
w -> w
mj_d -> mj_d
m_d -> m_d
mj -> mj
m -> m
tjsj -> tjsj
djzj -> djzj
t_- -> t_-
tj -> tj
t -> t
d_- -> d_-
dj -> dj
d -> d
llj_d -> lj_d
ll_d -> l_d
llj -> lj
ll -> l
lj_d -> lj_d
l_d -> l_d
lj -> lj
l -> l
nnj_d -> nj_d
nn_d -> n_d
nnj -> nj
nn -> n
nj_d -> nj_d
n_d -> n_d
rrj_d -> rj_d
rj_d -> rj_d
rr_d -> r_d
r_d -> r_d
rrj -> rj
rj -> rj
rr -> r
r -> r
sj -> sj
s -> s
zj -> zj
z -> z
kj -> kj
k -> k
gj -> gj
g -> g
xj -> xj
x -> x
gfj -> ∅ / _ #
gfj -> gfj
ngj_d -> ngj h
ng_d -> ng h
ngj -> nj / _ #
ngj -> ngj
ng -> ng
nj -> nj
n -> n
hj -> h
h -> h

0 -> 0
1 -> 1
2 -> 2
. -> .

- -> ∅
@ -> ∅
c -> ∅
j -> ∅
í -> ∅
ó -> ∅
_ -> ∅

TEST faas -> f aa s
TEST abhnnj -> au nj
TEST saghd -> s ai d
TEST saíoxt -> s i@ x t
TEST djeennamh -> dj ee n @ v
TEST taig -> t ai g
TEST saoll -> s ee l
TEST saulj -> s au lj
TEST kallj -> k ai lj
TEST krann -> k r au n
TEST kad -> k a d
TEST eenn -> i@ n
TEST sjee -> sj ee
TEST beidh -> b e gj
TEST fjeidhmj -> fj ai mj
TEST ljeighs -> lj ai s
TEST djesj -> dj e sj
TEST bjrjisjidh -> bj rj i sj @ gj
TEST xjannigh -> xj a n @ gj
TEST kjanníodh -> kj a n i@ x
TEST kjannithe -> kj a n @ h @
TEST i@rr -> i@ r
TEST sjiinj -> sj ii nj
TEST fjios -> fj i s
TEST imj -> ii mj
TEST sjinj -> sj i nj
TEST llobhr -> l au r
TEST kjannódh -> kj a n oo x
TEST bodhr -> b au r
TEST toghxaann -> t au x aa n
TEST oidhrjaxt -> ai rj a x t
TEST oighr -> ai r
TEST koillj -> k ii lj
TEST koillj@@ -> k i lj @
TEST domhnn -> d au n
TEST moor -> m oo r
TEST poll -> p au l
TEST polladh -> p o l @ x
TEST ubh@@gaann -> @ v @ g aa n
TEST bu@ -> b u@
TEST suimj -> s ii mj
TEST kuidj -> k i dj
TEST kuur -> k uu r
TEST kur -> k u r
TEST farjsj@@ngj -> f a rj sj @ nj